***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 13, 2026                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt 5KMC26AS-AU  A K 
.param
+vc0 = 2.806e-10	vc1 = 4.000e-11        vc2 = 1.150		vc3 = 3.300e-12		vc4 = 3.000e-1
+tc1 = 1.500e-2	        tc2 = 4.731e-2         tc3 = 3.001e-2	        tc4 = 2.751e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {5.182e-2*min(i,0)}
d1 A  A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 5.000e-13          n = 1.070             rs = 5.240e-3
+ibv = 1.0e-3	        nbv = 1.0               bv = 30.40
+ikf = 5.462
***** capacitance parameter *****
+cjo = 6.800e-9           m = 3.335e-1		vj = 5.656e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		 eg = 1.130	       xti = 3
+tikf = 1.000e-4       trs1 = 2.200e-3 
+tbv1 = 8.760e-4       tbv2 = -1.651e-7
.ends 5KMC26AS-AU
*$