***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 17, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SM8S24A-AU  A K 
.param
+vc0 = 1.577e-9		 vc1 = 1.283e-10		 vc2 = 1.000		 vc3 = 2.335e-10		 vc4 = 2.207e-1
+tc1 = 1.452e-2		 tc2 = 2.272e-2		 tc3 = 2.522e-2		 tc4 =2.262e-2	
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {2.302e-2*min(i,0)}
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.721e-12	       n = 1.078          rs = 4.211e-3
+ibv = 5.0e-3		 nbv = 1.000        bv = 28.1
+ikf = 1.403e+1
***** capacitance parameter *****
+cjo = 1.266e-11	   m = 3.319e-1		  vj = 3.905e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		      eg = 1.050		      xti = 3
+tikf = 6.000e-4       trs1 = 8.255e-4      
+tbv1 =7.687e-4	      tbv2 = -5.452e-7        
.ends SM8S24A-AU
*$