***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 23, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAV21WS-AU A K 
.param
+vc0 = 3.742e-9		 vc1 = 5.325e-11	 vc2 = 1.072e-15
+tc1 = 8.285e-2		 tc2 = 3.942e-2		
d1 A K diode
g1 K A value = {(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 3.876e-9		   n = 1.894		  rs = 3.356e-1		 ikf = 2.2e-2
+ibv = 0.1e-3		 nbv = 1		  bv = 275
***** capacitance parameter *****
+cjo = 7.272e-13	   m = 1.096e-1		  vj = 1.154
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.130		 xti = 3
+trs1 = 1.031e-4	trs2 = 2.825e-6		tikf = 4e-3		
.ends BAV21WS-AU
*$