***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 17, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************

.SUBCKT  PJA138K 20  10  30

Rg     10    1t    1

M1      2    1    3    3    DMOS    L=1u   W=1u

.MODEL DMOS NMOS ( VTO={1.3775*{-0.002*TEMP+1.05}}  KP=0.658

+ THETA=0.1  VMAX=2.2E5  LEVEL=3)   

Cgs     1t    3    50p IC=0

Rd     20    4    0.29 TC=0.0098

Dds     3    4    DDS

.MODEL     DDS    D(BV=49.8 TBV1=0.00083  M=0.36  CJO=23p   VJ=0.8)

E_E1         1 3 TABLE { V(1t, 30) } 

+ ((0, 0) 

+  (2.5, 2.42) 

+  (3, 2.9)

+  (3.5, 3.5)

+  (4, 4)

+  (4.5, 4.5)

+  (5, 5)

+  (10, 8)

+  (11, 9) )

Dbody   3   20    DBODY

.MODEL   DBODY    D(IS=1.4E-13   N=1   RS={-0.03*{TEMP-25}+0.6}   TT=100n VJ=0.8 )

Ra      4    2    0.28  TC=0.0065

Rs      3    5    10m

Ls      5    30   0.0001n

M2      1t    8    6    6   INTER

E2      8    6    4    1t   2

.MODEL   INTER    NMOS(VTO=0  KP=10   LEVEL=1) 

Cgdmax  7    4    10p IC=0

Rcgd    7    4    10meg

Dgd     6    4    DGD

Rdgd    4    6    10meg

.MODEL     DGD    D(M=0.3   CJO=68p   VJ=0.4)

M3      7    9    1t    1t   INTER

E3      9    1t    4    1   -2

.ENDS